git-choose

#!/usr/bin/env zsh
#
# git-choose — interactively select a repo and branch from configured URL prefixes.
#
# URL prefixes are discovered via git's url.<path>.insteadOf rewrite config.
# Only prefixes matching a configured scheme (choose.scheme, multi-value) are considered.
# Each prefix maps a URL scheme (e.g. sync://<remote>/, gitbundles://<remote>/) to a
# local directory, which is scanned for bare repos (*.git dirs) and bundle files.
#
# Subcommands:
#   list    Print all available URLs and exit.
#   clone   Interactively pick a repo and branch, then run git clone.
#   remote  Interactively pick one or more repos, then run git remote add for each.
#   (none)  Interactively pick a repo and branch, then print remote/url/branch.
#
# Configuration example:
#   [choose]
#       scheme = sync
#       scheme = gitbundles

function choose() {

	local subcommand="$1"
	[[ $# -gt 0 ]] && shift

	case "$subcommand" in
		clone|remote|list|'') ;;
		*) echo "Usage: $0:t [clone|remote|list]" >&2; return 1 ;;
	esac

	local -a schemes
	schemes=(${(@f)"$(git config get --all choose.scheme 2>/dev/null)"})
	if [[ ${#schemes} -eq 0 ]]; then
		echo "$0:t: no schemes configured; add choose.scheme entries to git config" >&2
		return 1
	fi
	local scheme_pattern="${(j:|:)schemes}"

	typeset -A path_for_url_prefix
	typeset -A remote_for_url_prefix

	local c
	for c in ${(@0):-"$(git config get --all --regex --show-name --null 'url\..*\.insteadof')"}; do
		local key="${c%%$'\n'*}"
		local value="${c#*$'\n'}"

		local repo_path_prefix="${${key#url.}%.insteadof}"
		local url_prefix="$value"

		if [[ "$url_prefix" =~ "(${scheme_pattern})://([^/]*)/" ]]; then
			path_for_url_prefix[$url_prefix]="$repo_path_prefix"
			remote_for_url_prefix[$url_prefix]="${match[2]}"
		fi
	done

	[[ ${#path_for_url_prefix} -gt 0 ]] || remote

	local repo_entries=()
	local up rpp repo
	for up in ${(k)path_for_url_prefix}; do
		rpp="${path_for_url_prefix[$up]}"
		while IFS= read -r repo; do
			[[ -n "$repo" ]] || continue
			repo_entries+=("${up}${repo}"$'\t'"${rpp%/}/${repo}"$'\t'"${remote_for_url_prefix[$up]}")
		done < <(cd "$rpp" && { fd -g -td '*.git'; fd -tf --exclude '*.git' } | sort -u | sed -E 's|/$||')
	done

	[[ ${#repo_entries} -gt 0 ]] || return 1

	if [[ "$subcommand" == list ]]; then
		printf '%s\n' "${repo_entries[@]%%$'\t'*}"
		return
	fi

	local -a fzf_extra=()
	if [[ "$subcommand" == remote ]]; then
		# Map existing remote URLs (with any trailing .git stripped, since git
		# resolves the suffix either way) to the remote names using them.
		typeset -A remote_names_for_url
		local rc
		for rc in ${(@0):-"$(git config get --all --regex --show-names --null '^remote\..*\.url$' 2>/dev/null)"}; do
			local rkey="${rc%%$'\n'*}"
			local rurl="${${rc#*$'\n'}%.git}"
			local rname="${${rkey#remote.}%.url}"
			[[ -n "$rurl" ]] || continue
			remote_names_for_url[$rurl]+="${remote_names_for_url[$rurl]:+, }${rname}"
		done
		local -a query_terms=()
		local i
		for (( i = 1; i <= ${#repo_entries}; ++i )); do
			local entry_url="${repo_entries[i]%%$'\t'*}"
			local names="${remote_names_for_url[${entry_url%.git}]-}"
			if [[ -n "$names" ]]; then
				repo_entries[i]+=$'\t'$'\e[32m✓ '"$names"$'\e[0m'
				query_terms+=("'${${entry_url##*/}%.git}'")
			else
				repo_entries[i]+=$'\t'
			fi
		done
		fzf_extra=(--multi --ansi --with-nth=1,4)
		# The ✓ marker is displayed only on already-added entries, so requiring
		# it in the query filters the list down to them; ctrl-a toggles that.
		fzf_extra+=(
			--header 'ctrl-a: toggle added-only filter'
			--bind 'ctrl-a:transform-query:case {q} in *✓*) printf %s {q} | sed "s/ *✓ *//g";; *) printf "%s ✓" {q};; esac'
		)
		query_terms=(${(u)query_terms})
		[[ ${#query_terms} -gt 0 ]] && fzf_extra+=(--query "${(j: | :)query_terms}")
	fi

	# Detect the terminal background up front so the fzf preview, which cannot
	# query the tty itself, can pick legible colors.
	export TERM_BACKGROUND="${TERM_BACKGROUND:-$(term-background 2>/dev/null || true)}"

	local -a selected
	selected=(${(@f)"$(printf '%s\n' "${repo_entries[@]}" | \
		fzf --reverse --height=-3 --delimiter=$'\t' --with-nth=1 --preview 'git-repo-info {2}' "${fzf_extra[@]}")"});

	[[ ${#selected} -gt 0 ]] || return 1;

	case "$subcommand" in
		clone|'')
			local repo_url="${selected[1]%%$'\t'*}"
			local remote_name="${selected[1]##*$'\t'}"
			local branch_ref="$(git ls-remote --branches "$repo_url" | fzf --reverse --height=~100% --delimiter=$'\t' --accept-nth=2 --select-1)";
			[[ -n "$branch_ref" ]] || return 1;
			local branch="${branch_ref#refs/heads/}"
			if [[ -z "$subcommand" ]]; then
				print "remote:\t$remote_name"
				print "url:\t$repo_url"
				print "branch:\t$branch"
			else
				git clone -b "$branch" -o "$remote_name" "$repo_url" "$@"
			fi
			;;
		remote)
			local -a existing_remotes
			existing_remotes=("${(@f)$(git remote)}")
			local line
			for line in "${selected[@]}"; do
				local -a fields=("${(@ps:\t:)line}")
				local repo_url="${fields[1]}"
				local remote_name="${fields[3]}"
				local unique_name="$remote_name"
				local n=0
				while (( ${existing_remotes[(Ie)$unique_name]} )); do
					(( ++n ))
					unique_name="${remote_name}-${n}"
				done
				git remote add "$unique_name" "$repo_url"
				existing_remotes+=("$unique_name")
			done
			;;
	esac
}

choose "$@"